Self-Descriptive Plot and Data using Tcl and Rrdtool

#! /usr/local/bin/tclsh
#
# Input file definition:
# 
# HEADER
# HOST=
# DS=:                          (allow multiple DS)
# GRAPH=                      (allow multiple GRAPH)
# (colon separated)
# - image filename
# - y-axis lower limit
# - y-axis upper limit
# - Title
# - y-axis label
# - scale factor
# - data source to be graphed (comma separated, # separated for each data source details)
#   - data source name
#   - graph type (LINE2, AREA, ...)
#   - RGB colour code
#    ....
#
#
# Example:
#   HOST=linux12
#   DS=ifInOctets:COUNTER
#   DS=ifOutOctets:COUNTER
#   DS=usr:GAUGE
#   DS=sys:GAUGE
#   DS=wio:GAUGE
#   DS=idl:GAUGE
#   GRAPH=linux12-net.png:0:U:Network Utilisation (linux12):Kbps:0.0078125:ifInOctets#AREA#00ff00,ifOutOctets#LINE2#0000ff
#   GRAPH=linux12-cpu.png:0:100:CPU Utilisation (linux12):Percent:1.0:usr#AREA#ff0000,sys#STACK#00ff00,wio#STACK#0000ff,idl#STACK#ffffff
#   1141799482 2817539218 2430130990 9 3 2 86
#   1141799782 2817550436 2430187155 5 1 2 91
#   1141800082 2817561155 2430236468 6 2 2 90
#   1141800383 2817571652 2430291354 7 2 2 89
#   1141800683 2817640317 2430599915 6 1 2 91
#   1141800983 2817702016 2430697970 5 1 2 91



if { $argc != 1 } {
 puts stderr "Usage: $argv0 "
 exit 1
}
set inputFile [lindex $argv 0]
if { [file exists $inputFile] == 0 } {
 puts stderr "Error. $inputFile does not exist"
 exit 2
}


proc getHeader { f } {
 global rrdplot

 set fp [open $f r]
 set rrdplot(graph) {}
 set rrdplot(ds) {}
 while { [gets $fp line] >= 0 } {
  switch -regexp $line {
   {^HOST=} {
    set rrdplot(host) [lindex [split $line =] 1]
   }
   {^DS=} {
    lappend rrdplot(ds) [lindex [split $line =] 1]
   }
   {^GRAPH=} {
    lappend rrdplot(graph) [lindex [split $line =] 1]
   }
   {^[1-9][0-9]+} {
    break
   }
   default {
    puts stderr "Error. cannot understand the format"
    close $fp
    exit 3
   }
  }
 }
 close $fp
}


proc getTime { f } {
 global rrdplot

 set fp [open $f r]
 while { [gets $fp line] >= 0 } {
  switch -regexp $line {
   {^[A-Z]+=} { continue }
   {^[1-9][0-9]*} { break }
  }
 }
 set rrdplot(start1) [lindex $line 0]
 gets $fp line
 set rrdplot(start2) [lindex $line 0]
 set rrdplot(start0) [expr $rrdplot(start1) - 1]
 set rrdplot(step) [expr $rrdplot(start2) - $rrdplot(start1)]
 set rrdplot(heartbeat) [expr $rrdplot(step) * 2]

 # end time 
 while { [gets $fp line] >= 0 } {
  set prevline $line
  continue
 }
 set rrdplot(end) [lindex $prevline 0]
 close $fp
}


proc createRrd {} {
 global rrdplot

 set rrdplot(rrdfile) "$rrdplot(host).rrd"
 set rrdargs "$rrdplot(rrdfile) -b $rrdplot(start0) -s $rrdplot(step)"
 foreach d $rrdplot(ds) {
  set name [lindex [split $d :] 0]
  set type [lindex [split $d :] 1]
  append rrdargs " DS:$name:$type:$rrdplot(heartbeat):0:U"
 }
 append rrdargs " RRA:AVERAGE:0.5:1:600  RRA:AVERAGE:0.5:6:700"
 append rrdargs " RRA:AVERAGE:0.5:24:775 RRA:AVERAGE:0.5:228:797"
 append rrdargs " RRA:MIN:0.5:1:600      RRA:MIN:0.5:6:700"
 append rrdargs " RRA:MIN:0.5:24:775     RRA:MIN:0.5:228:797"
 append rrdargs " RRA:MAX:0.5:1:600      RRA:MAX:0.5:6:700"
 append rrdargs " RRA:MAX:0.5:24:775     RRA:MAX:0.5:228:797"

 eval exec rrdtool create $rrdargs
}


proc populateRrd { f } {
 global rrdplot

 set fp [open $f r]

 # skip headers
 while { [gets $fp line] >= 0 } {
  if { [regexp {^[1-9][0-9]+} $line] } {
   exec rrdtool update $rrdplot(rrdfile) [join $line :]
  }
 }
 close $fp
}


proc graphRrd { } {
 global rrdplot

 foreach i $rrdplot(graph) {
  set rrdargs {}
  foreach { png lower upper title ytitle factor ds } [split $i :] {}
  append rrdargs " $png -s $rrdplot(start1) -e $rrdplot(end)"
  append rrdargs " -t \"$title\" -v \"$ytitle\""
  append rrdargs " --rigid --lower-limit $lower"
  if { ![string equal U $upper] } {
   append rrdargs " --upper-limit $upper"
  }

  # DEF
  foreach j [split $ds ,] {
   foreach { var type colour } [split $j #] {}
   append rrdargs " DEF:$var=$rrdplot(rrdfile):$var:AVERAGE"
  }

  # CDEF
  set p 1
  foreach j [split $ds ,] {
   foreach { var type colour } [split $j #] {}
   append rrdargs " CDEF:p$p=$var,$factor,*"
   incr p
  }

  # state the sampling period
  # note: rrd comment cannot allow colon !!
  set start [clock format $rrdplot(start1) -format {%Y-%m-%d %Hh%Mm}]
  set end [clock format $rrdplot(end) -format {%Y-%m-%d %Hh%Mm}]
  append rrdargs " COMMENT:\"Sampling Period  From $start\\n\""
  append rrdargs " COMMENT:\"                 To   $end\\n\""

  # find the length of the longest variable name
  # allow format to align correctly
  set max 0
  foreach j [split $ds ,] {
   foreach { var type colour } [split $j #] {}
   set nvar [string length $var]
   if { $nvar > $max } { set max $nvar }
  }

  # LINE/AREA/STACK
  set p 1
  foreach j [split $ds ,] {
   foreach { var type colour } [split $j #] {}
   set varMax [format "%-${max}s" $var]
   append rrdargs " $type:p$p#$colour:'$varMax'"
   append rrdargs " 'GPRINT:p$p:MIN:min=%6.2lf'"
   append rrdargs " 'GPRINT:p$p:AVERAGE:avg=%6.2lf'"
   append rrdargs " 'GPRINT:p$p:MAX:max=%6.2lf'"
   append rrdargs " COMMENT:\"\\n\""
   incr p
  }

  # eval Rrd::graph $rrdargs
  # eval exec rrdtool graph $rrdargs
  # ERROR: 'P' is not a valid function name
  #    while executing
  #
  # work around by writing it to external file
  execRrdgraph $rrdargs
 }


}

proc execRrdgraph { s } {
 set tmpFile [format {.%s-%d} $::argv0 [pid]]
 set fp [open $tmpFile w]
 puts $fp "rrdtool graph $s"
 close $fp
 exec chmod +x $tmpFile
 exec $tmpFile
 file delete -force $tmpFile
}
 

getHeader $inputFile
getTime $inputFile
createRrd 
populateRrd $inputFile
graphRrd